Skeetendo

Both of these questions can be answered by modifying the routine called "PlayBattleMusic" from audio.asm.

Map songs can be customized by editing data/map_songs.asm.

Accomplishing this would be a rather large effort and should be revisited once you have a strong grasp of the Gameboy memory map.

Currently, custom trainer moves only apply to gym leaders and each gym leader can only have 1 custom move. If you want to expand either of these limitations, you would need to modify the routine called "ReadTrainer" from engine/battle/read_trainer_party.asm.
I am not sure what you are referring to when you say "Team Nives".

Editing the value for the repel counters can be done by modifying the routines called "ItemUseRepel", "ItemUseSuperRepel", and "ItemUseMaxRepel" from engine/items/items.asm.
Editing the Safari Zone steps can be done by modifying "SafariZoneEntranceText4" from scripts/SafariZoneGate.asm.

On the Gameboy, the general purpose CPU registers are 8-bits.
The 'b' register is one of these 8-bit registers.
8-bit numbers can range from 0 to 255, inclusive.
Therefore, you cannot put a number as large as 400 into the 'b' register.

Regarding the Rocket battle theme, take a look at this excerpt from the routine "PlayBattleMusic":

.notGymLeaderBattle
    ld a, [wCurOpponent]
    cp OPP_ID_OFFSET
    jr c, .wildBattle
    cp OPP_SONY3
    jr z, .finalBattle
    cp OPP_LANCE
    jr nz, .normalTrainerBattle
    ld a, MUSIC_GYM_LEADER_BATTLE ; lance also plays gym leader theme
    jr .playSong
.normalTrainerBattle
    ld a, MUSIC_TRAINER_BATTLE
    jr .playSong
.finalBattle
    ld a, MUSIC_FINAL_BATTLE
    jr .playSong
.wildBattle
    ld a, MUSIC_WILD_BATTLE
.playSong
    jp PlayMusic

Since you are new to assembly, let's go through this step-by-step:

ld a, [wCurOpponent]

This takes an 8-bit value from ram and stores it in the 8-bit register 'a'.
This ram location is named wCurOpponent, for readability. It represents the ID of the Pokemon or trainer class the player is about to battle.

cp OPP_ID_OFFSET
jr c, .wildBattle

The first line compares the value in the 'a' register with the value OPP_ID_OFFSET (a constant equal to 200). This is because all Pokemon IDs are less than 200 and all trainer class IDs are greater than 200.
This 'cp' compare instruction will set the 'c' flag if register 'a' contains a value smaller than OPP_ID_OFFSET (and unsets the 'c' flag otherwise). (This instruction also sets another flag discussed later.)
The 'c' flag is a CPU status flag that gets set (and unset) by certain instructions and can be used by other instructions to make decisions. (Flags can only have the value 1 (set) or 0 (unset))
In this case, the next instruction (jr c) will "jump" (move to a new location in code) only if the 'c' flag is set.
Therefore, these two lines of code will jump to a new location (labelled as '.wildBattle' further down in the routine) if the ID of the current opponent is a Pokemon ID.
Otherwise, the ID is a trainer class ID, so code execution continues to the next line (because the jump was not taken).

cp OPP_SONY3
jr z, .finalBattle

Somewhat similar to the previous few lines of code, this will compare the value in the 'a' register to the trainer class ID, OPP_SONY3 (the final rival battle after the Elite Four).
However this time, the 'jr z' instruction will only jump to the new destination if the 'z' flag is set.
The 'z' flag is another CPU status flag. In this case, the 'cp' instruction will set the 'z' flag if the value in register 'a' is equal to OPP_SONY3 (and unsets the 'z' flag otherwise).
So, these few lines of code jump to '.finalBattle' if the opponent is the final rival.

cp OPP_LANCE
jr nz, .normalTrainerBattle
ld a, MUSIC_GYM_LEADER_BATTLE ; lance also plays gym leader theme
jr .playSong

Again, this is somewhat similar to the previous cases.
The 'a' register is compared to OPP_LANCE, which will set or unset the 'c' and 'z' flags appropriately.
The 'jr nz' instruction will jump to the new destination (.normalTrainerBattle) if the opponent is NOT Lance.
Otherwise, if the opponent is lance, the value of MUSIC_GYM_LEADER_BATTLE is loaded into the 'a' register.
Now this time, the 'jr' instruction is an unconditional jump (because there is no 'c', 'nc', 'z', or 'nz' operand).
If an unconditional jump instruction is executed, then the CPU will always jump to the destination (.playSong in this case).

.normalTrainerBattle
    ld a, MUSIC_TRAINER_BATTLE
    jr .playSong
.finalBattle
    ld a, MUSIC_FINAL_BATTLE
    jr .playSong
.wildBattle
    ld a, MUSIC_WILD_BATTLE
.playSong
    jp PlayMusic

Lastly, these are all the labels referenced above throughout the routine.
Each of these labels loads the appropriate song ID into the 'a' register and then concludes the routine by jumping to the 'PlayMusic' routine. (A core sound engine routine.)

If this was a little hard to follow, you can review the Gameboy instruction set here and here.

Once you are familiar with the CPU registers and instructions, you should be able to come up with an approach for modifying this routine to assign a custom song to other trainer class IDs (like Rockets).

One of the limitations of Pokemon Red is that the game contains 3 entire identical copies of the sound engine. Each of the copies of the sound engine is grouped with a different set of songs.

The battle engine always uses sound engine #2, which contains the battle themes as well as all the battle attack sound effects.
All the other songs (overworld themes, title screen, credits, etc) are split across sound engine #1 and sound engine #3.

Attempting to play a song while the wrong sound engine is loaded will result in glitchy behavior.

There's no easy way around this limitation, but you can use this hack of pokered instead:
https://github.com/dannye/pokered-crysaudio

This replaces all 3 copies of the sound engine with a single copy of the Pokemon Crystal sound engine.
The Pokemon Crystal sound engine is pretty similar to the Pokemon Red sound engine but has extra features and greater flexibility. For example, you can play a song from any bank at any time.

Your other option is to add a new song to sound engine #2 (take a look at audio.asm)

Luckily, there is already a branch of pokered-gbc with crysaudio included.

The only thing that branch is missing would be a few commits I added to it later, for polished map support and to adjust the colors on a few things and stuff. Shouldn't be too difficult to merge the handful of new commits from 'master' into 'crysaudio' though.

In constants.asm, change the value of GEN_2_MUSIC from 1 to 0

Look at crysaudio/red_pointers.asm to see why this works

Haha, glad to help