Skeetendo

DrawBadges: ; ea03 (3:6a03)
; Draw 4x2 gym leader faces, with the faces replaced by
; badges if they are owned. Used in the player status screen.

; In Japanese versions, names are displayed above faces.
; Instead of removing relevant code, the name graphics were erased.

; Tile ids for face/badge graphics.
    ld de, $cd3f
    ld hl, .FaceBadgeTiles
    ld bc, 8
    call CopyData

; Booleans for each badge.
    ld hl, $cd49
    ld bc, 8
    xor a
    call FillMemory

; Alter these based on owned badges.
    ld de, $cd49
    ld hl, $cd3f
    ld a, [W_OBTAINEDBADGES]
    ld b, a
    ld c, 8
.CheckBadge
    srl b
    jr nc, .NextBadge
    ld a, [hl]
    add 4 ; Badge graphics are after each face
    ld [hl], a
    ld a, 1
    ld [de], a
.NextBadge
    inc hl
    inc de
    dec c
    jr nz, .CheckBadge

; Draw two rows of badges.
    ld hl, $cd3d
    ld a, $d8 ; [1]
    ld [hli], a
    ld [hl], $60 ; First name

    FuncCoord 2, 11
    ld hl, Coord
    ld de, $cd49
    call .DrawBadgeRow

    FuncCoord 2, 14
    ld hl, Coord
    ld de, $cd49 + 4
;    call .DrawBadgeRow
;    ret
; ea4c

.DrawBadgeRow ; ea4c (3:6a4c)
; Draw 4 badges.

    ld c, 4
.DrawBadge
    push de
    push hl

; Badge no.
    ld a, [$cd3d]
    ld [hli], a
    inc a
    ld [$cd3d], a

; Names aren't printed if the badge is owned.
    ld a, [de]
    and a
    ld a, [$cd3e]
    jr nz, .SkipName
    call .PlaceTiles
    jr .PlaceBadge

.SkipName
    inc a
    inc a
    inc hl

.PlaceBadge
    ld [$cd3e], a
    ld de, 20 - 1
    add hl, de
    ld a, [$cd3f]
    call .PlaceTiles
    add hl, de
    call .PlaceTiles

; Shift badge array back one byte.
    push bc
    ld hl, $cd3f + 1
    ld de, $cd3f
    ld bc, 8
    call CopyData
    pop bc

    pop hl
    ld de, 4
    add hl, de

    pop de
    inc de
    dec c
    jr nz, .DrawBadge
    ret

.PlaceTiles
    ld [hli], a
    inc a
    ld [hl], a
    inc a
    ret

.FaceBadgeTiles
    db $20, $28, $30, $38, $40, $48, $50, $58